Classes:Minotaur

From ZDoom Wiki
Jump to: navigation, search
Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things:
  1. You do not need to copy that actor, since it is already defined.
  2. In fact, it's not just useless, it's actually harmful as it can cause problems.
  3. If you want to modify it, or use a modified version, using inheritance is the way to go.
  4. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.
  5. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.
Maulotaur
Actor type Monster Game MiniHereticLogoIcon.png
DoomEd Number 9 Class Name Minotaur


Classes: Minotaur
 →MinotaurFriend

Maulotaurs are giant minotaurs who wield mauls, which explains their very D&Dish portmanteau name. They sport nose rings and, apparently more modest than their distant Doom cousins, wear loincloths. The second-strongest monster of Heretic, surpassed only by D'Sparil himself, they can be considered the Heretic equivalent of Doom's Cyberdemons; though despite their greater variety of attacks they are significantly weaker. For this reason, they are found in large numbers when they are used in boss levels.

In Hexen.wad, the attack sprites are lettered from F to K instead of from U to Z, and the death sprites are missing. For this reason, they are renamed at load time by ZDoom and the native action A_MinotaurDeath causes the maulotaur to enter the FadeOut state if the death sprites are missing.

When slain, they may randomly drop mystic urns and flame orbs with ten charges.

Minotaurs use the following actor fields for specific purposes:

special1
Serves as a countdown timer for the Charge attack.
special2
Used to prevent repeating the Hammer attack more than once.

Note: Maulotaurs are invulnerable while charging, dark servants aren't.

DECORATE definition

ACTOR Minotaur native
{
  Health 3000
  Radius 28
  Height 100
  Mass 800
  Speed 16
  Damage 7
  PainChance 25
  Monster
  +DROPOFF
  +FLOORCLIP
  +BOSS
  +NORADIUSDMG
  +DONTMORPH
  +NOTARGET
  +BOSSDEATH
  SeeSound "minotaur/sight"
  AttackSound "minotaur/attack1"
  PainSound "minotaur/pain"
  DeathSound "minotaur/death"
  ActiveSound "minotaur/active"
  DropItem "ArtiSuperHealth", 51
  DropItem "PhoenixRodAmmo", 84, 10

  action native A_MinotaurDecide();
  action native A_MinotaurAtk1();
  action native A_MinotaurAtk2();
  action native A_MinotaurAtk3();
  action native A_MinotaurCharge();
  action native A_MinotaurLook();
  action native A_MinotaurRoam();
  action native A_MinotaurChase();
  action native A_MinotaurDeath();

  States
  {
  Spawn:
    MNTR AB 10 A_MinotaurLook
    Loop
  Roam:
    MNTR ABCD 5 A_MinotaurRoam
    Loop
  See:
    MNTR ABCD 5 A_MinotaurChase
    Loop
  Melee:
    MNTR V 10 A_FaceTarget
    MNTR W 7 A_FaceTarget
    MNTR X 12 A_MinotaurAtk1
    Goto See
  Missile:
    MNTR V 10 A_MinotaurDecide
    MNTR Y 4 A_FaceTarget
    MNTR Z 9 A_MinotaurAtk2
    Goto See
  Hammer:
    MNTR V 10 A_FaceTarget
    MNTR W 7 A_FaceTarget
    MNTR X 12 A_MinotaurAtk3
    Goto See
  HammerLoop:
    MNTR X 12
    Goto Hammer
  Charge:
    MNTR U 2 A_MinotaurCharge
    Loop
  Pain:
    MNTR E 3
    MNTR E 6 A_Pain
    Goto See
  Death:
    MNTR F 6 A_MinotaurDeath
    MNTR G 5
    MNTR H 6 A_Scream
    MNTR I 5
    MNTR J 6
    MNTR K 5
    MNTR L 6
    MNTR M 5 A_NoBlocking
    MNTR N 6
    MNTR O 5
    MNTR P 6
    MNTR Q 5
    MNTR R 6
    MNTR S 5
    MNTR T -1 A_BossDeath
    Stop
  FadeOut:
    MNTR E 6
    MNTR E 2 A_Scream
    MNTR E 5 A_SpawnItemEx("MinotaurSmokeExit")
    MNTR E 5
    MNTR E 5 A_NoBlocking
    MNTR E 5
    MNTR E 5 A_SetTranslucent(0.66, 0)
    MNTR E 5 A_SetTranslucent(0.33, 0)
    MNTR E 10 A_BossDeath
    Stop
  }
}

Related Classes

MinotaurFX1, MinotaurFX2 and MinotaurFX3 are used for the maulotaur's ranged attacks.