Classes:Snake

Note: Wait! Stop! You do not need to copy this actor's code into your project! Here's why: This actor is already defined in GZDoom, there's no reason to define it again. In fact, trying to define an actor with the same name will cause an error (because it already exists). If you want to make your own version of this actor, use inheritance. Definitions for existing actors are put on the wiki for reference purpose only.

Ophidian
Actor type	Monster	Game	(Heretic)
DoomEd Number	92	Class Name	Snake
Spawn ID	132	Identifier	T_SNAKE

Classes: Snake
A serpentine enemy wielding a magic trident able to throw projectiles of ice and fire. They are tougher than they look.

DECORATE definition

ACTOR Snake
{
  Health 280
  Radius 22
  Height 70
  Speed 10
  PainChance 48
  Monster
  +FLOORCLIP
  AttackSound "snake/attack"
  SeeSound "snake/sight"
  PainSound "snake/pain"
  DeathSound "snake/death"
  ActiveSound "snake/active"
  Obituary "$OB_SNAKE"
  DropItem "PhoenixRodAmmo", 84, 5
  States
  {
  Spawn:
    SNKE AB 10 A_Look
    Loop
  See:
    SNKE ABCD 4 A_Chase
    Loop
  Missile:
    SNKE FF 5 A_FaceTarget
    SNKE FFF 4 A_CustomMissile("SnakeProjA", 32, 0, 0, CMF_CHECKTARGETDEAD)
    SNKE FFF 5 A_FaceTarget
    SNKE F 4 A_CustomMissile("SnakeProjB", 32, 0, 0, CMF_CHECKTARGETDEAD)
    Goto See
  Pain:
    SNKE E 3
    SNKE E 3 A_Pain
    Goto See
  Death:
    SNKE G 5
    SNKE H 5 A_Scream
    SNKE IJKL 5
    SNKE M 5 A_NoBlocking
    SNKE NO 5
    SNKE P -1
    Stop
  }
}