Classes:FireDemon

Note: Wait! Stop! You do not need to copy this actor's code into your project! Here's why: This actor is already defined in GZDoom, there's no reason to define it again. In fact, trying to define an actor with the same name will cause an error (because it already exists). If you want to make your own version of this actor, use inheritance. Definitions for existing actors are put on the wiki for reference purpose only.

Afrit
Actor type	Monster	Game	(Hexen)
DoomEd Number	10060	Class Name	FireDemon
Spawn ID	5	Identifier	T_FIREGARGOYLE

Classes: FireDemon

A close cousin of the gargoyles from Heretic, the afrit looks like a small black gargoyle wreathed in flames. It is more aggressive and mobile than the gargoyles, though, and often sends volleys of fireballs while strafing.

DECORATE definition

ACTOR FireDemon
{
  Health 80
  ReactionTime 8
  PainChance 1
  Speed 13
  Radius 20
  Height 68
  Mass 75
  Damage 1
  Monster
  +DROPOFF
  +NOGRAVITY
  +FLOAT
  +FLOORCLIP
  +INVULNERABLE
  +TELESTOMP
  SeeSound "FireDemonSpawn"
  PainSound "FireDemonPain"
  DeathSound "FireDemonDeath"
  ActiveSound "FireDemonActive"
  Obituary "$OB_FIREDEMON" // "%o tasted an Afrit's fire."

  action native A_FiredRocks();
  action native A_FiredChase();
  action native A_FiredAttack();
  action native A_FiredSplotch();

  States
  {
  Spawn:
    FDMN X 5 Bright
    FDMN EFG 10 Bright A_Look
    Goto Spawn+1
  See:
    FDMN E 8 Bright
    FDMN F 6 Bright
    FDMN G 5 Bright
    FDMN F 8 Bright
    FDMN E 6 Bright
    FDMN G 7 Bright A_FiredRocks
    FDMN HI 5 Bright
    FDMN J 5 Bright A_UnSetInvulnerable
  Chase:
    FDMN ABC 5 Bright A_FireDChase
    Loop
  Pain:
    FDMN D 0 Bright A_UnSetInvulnerable
    FDMN D 6 Bright A_Pain
    Goto Chase
  Missile:
    FDMN K 3 Bright A_FaceTarget
    FDMN KKK 5 Bright A_FiredAttack
    Goto Chase
  Crash:
  XDeath:
    FDMN M 5 A_FaceTarget
    FDMN N 5 A_NoBlocking
    FDMN O 5 A_FiredSplotch
    Stop
  Death:
    FDMN D 4 Bright A_FaceTarget
    FDMN L 4 Bright A_Scream
    FDMN L 4 Bright A_NoBlocking
    FDMN L 200 Bright
    Stop
  Ice:
    FDMN R 5 A_FreezeDeath
    FDMN R 1 A_FreezeDeathChunks
    Wait
  }
}