Classes:EntitySecond

Note: Wait! Stop! You do not need to copy this actor's code into your project! Here's why: This actor is already defined in GZDoom, there's no reason to define it again. In fact, trying to define an actor with the same name will cause an error (because it already exists). If you want to make your own version of this actor, use inheritance. Definitions for existing actors are put on the wiki for reference purpose only.

Alien sub-entity
Actor type	Monster	Game	(Strife)
DoomEd Number	None	Class Name	EntitySecond
Conversation ID	75	Puzzle Item ID	N/A

Classes: SpectralMonster→EntitySecond
Thought you'd killed the Entity, did you? Think again! Three of these appear when the Entity dies. They are weaker than the Entity, as they use only the first two forms of the Sigil and have less health. If a level contains one or more of these, all of them dying ends the level instantly.

DECORATE definition

ACTOR EntitySecond : SpectralMonster
{
  Health 990
  PainChance 255
  Speed 14
  Radius 130
  Height 200
  FloatSpeed 5
  Mass 1000
  Monster
  +SPECIAL
  +NOGRAVITY
  +FLOAT
  +SHADOW
  +NOTDMATCH
  +DONTMORPH
  +NOBLOCKMONST
  +INCOMBAT
  +LOOKALLAROUND
  +SPECTRAL
  +NOICEDEATH
  MinMissileChance 150
  RenderStyle Translucent
  Alpha 0.25
  SeeSound "alienspectre/sight"
  AttackSound "alienspectre/blade"
  PainSound "alienspectre/pain"
  DeathSound "alienspectre/death"
  ActiveSound "alienspectre/active"
  Obituary "$OB_ENTITY" // "%o felt the wrath of The One God."

  action native A_SubEntityDeath();

  States
  {
  Spawn:
    MNAL R 10 Bright A_Look
    Loop
  See:
    MNAL R 5 Bright A_SentinelBob
    MNAL ST 5 Bright A_Chase
    MNAL U 5 Bright A_SentinelBob
    MNAL V 5 Bright A_Chase
    MNAL W 5 Bright A_SentinelBob
    Loop
  Melee:
    MNAL S 4 Bright A_FaceTarget
    MNAL R 4 Bright A_CustomMeleeAttack((random[SpectreMelee](0, 255)&9)*5)
    MNAL T 4 Bright A_SentinelBob
    Goto See+1
  Missile:
    MNAL W 4 Bright A_FaceTarget
    MNAL U 4 Bright A_CustomMissile("SpectralLightningH3", 32, 0)
    MNAL V 4 Bright A_SentinelBob
    Goto See+4
  Pain:
    MNAL R 2 Bright A_Pain
    Goto See
  Death:
    MDTH A 3 Bright A_Scream
    MDTH B 3 Bright A_TossGib
    MDTH C 3 Bright A_NoBlocking
    MDTH DEFGHIJKLMN 3 Bright A_TossGib
    MDTH O 3 Bright A_SubEntityDeath
    Stop
  }
}