Classes:BFG10K

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do NOT need to copy that actor, since it is already defined. In fact, it's not just useless, it will cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.

BFG 10000
Actor type	Weapon	Game	(Skulltag)
DoomEd Number	5013	Class Name	BFG10K
Spawn ID	165	Identifier	T_BFG10000

Warning: This class is a Skulltag-specific actor that is not included in ZDoom!

Classes: Inventory→Weapon→DoomWeapon→BFG10K

The most powerful weapon in the Skulltag arsenal, the BFG10k is essentially a rapid-fire, hitscan weapon with a massive blast radius. For this reason, it's usually very hard to actually get your hands on it.

DECORATE definition

ACTOR BFG10K : DoomWeapon 5013
{
  SpawnID 165
  Radius 20
  Height 20
  Weapon.Selectionorder 2800
  Weapon.AmmoUse 5
  Weapon.AmmoGive 40
  Weapon.AmmoType "Cell"
  Weapon.Kickback 100
  Weapon.SlotNumber 7 // This line isn't in skulltag.pk3, which instead defines the slot directly in DoomPlayer
  Inventory.Pickupmessage "$PICKUP_BFG10K" // "You got the BFG10000!  Hell, yes!"
  +WEAPON.NOAUTOFIRE
  +WEAPON.NOLMS
  States
  {
  Spawn:
    BFG2 A -1
    Stop
  Ready:
    BG2G A 0 A_PlaySound ("weapons/bfg10kidle")
    BG2G A 1 A_WeaponReady
    BG2G A 1 A_WeaponReady
    BG2G A 1 A_WeaponReady
    BG2G B 1 A_WeaponReady
    BG2G B 1 A_WeaponReady
    BG2G B 1 A_WeaponReady
    BG2G C 1 A_WeaponReady
    BG2G C 1 A_WeaponReady
    BG2G C 1 A_WeaponReady
    BG2G D 1 A_WeaponReady
    BG2G D 1 A_WeaponReady
    BG2G D 1 A_WeaponReady
    Loop
  Deselect:
    BG2G E 1 A_Lower
    Loop
  Select:
    BG2G E 1 A_Raise
    Loop
  Fire:
    BG2G E 20 A_PlaySound ("weapons/bfg10kf")
    BG2G F 4
    BG2G G 1
    BG2G H 1
    BG2G I 1
    BG2G J 1
    Goto Hold
  Hold:
    BG2G K 2 A_GunFlash
    BG2G L 2 A_FireBullets(0,0,1,0,"BFG10kShot")
    BG2G M 2
    BG2G N 0 A_ReFire
    BG2G O 35 A_PlaySound ("weapons/bfg10kcool")
    Goto Ready
  Flash:
    TNT1 A 2 Bright A_Light1
    TNT1 A 3 Bright
    Goto LightDone
    Stop
  }
}