Classes:Programmer

Note: Wait! Stop! You do not need to copy this actor's code into your project! Here's why: This actor is already defined in GZDoom, there's no reason to define it again. In fact, trying to define an actor with the same name will cause an error (because it already exists). If you want to make your own version of this actor, use inheritance. Definitions for existing actors are put on the wiki for reference purpose only.

The Programmer
Actor type	Monster	Game	(Strife)
DoomEd Number	71	Class Name	Programmer
Conversation ID	95	Puzzle Item ID	N/A

Classes: Programmer
The creator of the AI controlling the Acolytes, and holder of the first Sigil piece. He uses Sigil 1 attacks.

DECORATE definition

ACTOR Programmer
{
  Health 1100
  PainChance 50
  Speed 26
  FloatSpeed 5
  Radius 45
  Height 60
  Mass 800
  Damage 4
  Monster
  +NOGRAVITY
  +FLOAT
  +NOBLOOD
  +NOTDMATCH
  +DONTMORPH
  +NOBLOCKMONST
  +LOOKALLAROUND
  +NOICEDEATH
  +NOTARGETSWITCH
  DamageFactor "Fire", 0.5
  MinMissileChance 150
  AttackSound "programmer/attack"
  PainSound "programmer/pain"
  DeathSound "programmer/death"
  ActiveSound "programmer/active"
  Obituary "$OB_PROGRAMMER" // "%o was deleted by the Programmer."
  DropItem "Sigil1"

  action native A_ProgrammerMelee();
  action native A_SpawnProgrammerBase();
  action native A_ProgrammerDeath();
  action native A_SpotLightning();

  States
  {
  Spawn:
    PRGR A 5 A_Look
    PRGR A 1 A_SentinelBob
    Loop
  See:
    PRGR A 160 A_SentinelBob
    PRGR BCD 5 A_SentinelBob
    PRGR EF 2 A_SentinelBob
    PRGR EF 3 A_Chase
    Goto See+4
  Melee:
    PRGR E 2 A_SentinelBob
    PRGR F 3 A_SentinelBob
    PRGR E 3 A_FaceTarget
    PRGR F 4 A_ProgrammerMelee
    Goto See+4
  Missile:
    PRGR G 5 A_FaceTarget
    PRGR H 5 A_SentinelBob
    PRGR I 5 Bright A_FaceTarget
    PRGR J 5 Bright A_SpotLightning
    Goto See+4
  Pain:
    PRGR K 5 A_Pain
    PRGR L 5 A_SentinelBob
    Goto See+4
  Death:
    PRGR L 7 Bright A_TossGib
    PRGR M 7 Bright A_Scream
    PRGR N 7 Bright A_TossGib
    PRGR O 7 Bright A_NoBlocking
    PRGR P 7 Bright A_TossGib
    PRGR Q 7 Bright A_SpawnProgrammerBase
    PRGR R 7 Bright
    PRGR S 6 Bright
    PRGR TUVW 5 Bright
    PRGR X 32 Bright
    PRGR X -1 Bright A_ProgrammerDeath
    Stop
  }
}