Classes:Stalker

From ZDoom Wiki
Jump to: navigation, search
Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things:
  1. You do not need to copy that actor, since it is already defined.
  2. In fact, it's not just useless, it's actually harmful as it can cause problems.
  3. If you want to modify it, or use a modified version, using inheritance is the way to go.
  4. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.
  5. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.
Stalker
Actor type Monster Game MiniStrifeLogoIcon.png
DoomEd Number 186 Class Name Stalker
Conversation ID 92 Puzzle Item ID N/A


Classes: Stalker
Small spider-like robots in Strife which use only melee attacks. They can walk on the ceiling and drop when you get close. In Strife1.wad, the sprites are actually named SPID* and are renamed at load-time by ZDoom.

DECORATE definition

ACTOR Stalker
{
  Health 80
  PainChance 40
  Speed 16
  Radius 31
  Height 25
  Monster
  +NOGRAVITY
  +DROPOFF
  +NOBLOOD
  +SPAWNCEILING
  +INCOMBAT
  +NOVERTICALMELEERANGE
  MaxDropOffHeight 32
  MinMissileChance 150
  SeeSound "stalker/sight"
  AttackSound "stalker/attack"
  PainSound "stalker/pain"
  DeathSound "stalker/death"
  ActiveSound "stalker/active"
  HitObituary "$OB_STALKER" // "%o was bugged by a Stalker."

  action native A_StalkerLookInit();
  action native A_StalkerChaseDecide();
  action native A_StalkerWalk();
  action native A_StalkerDrop();
  action native A_StalkerAttack();

  States
  {
  Spawn:
    STLK A 1 A_StalkerLookInit
    Loop
  LookCeiling:
    STLK A 10 A_Look
    Loop
  LookFloor:
    STLK J 10 A_Look
    Loop
  See:
    STLK A 1 Slow A_StalkerChaseDecide
    STLK ABB 3 Slow A_Chase
    STLK C 3 Slow A_StalkerWalk
    STLK C 3 Slow A_Chase
    Loop
  Melee:
    STLK J 3 Slow A_FaceTarget
    STLK K 3 Slow A_StalkerAttack
  SeeFloor:
    STLK J 3 A_StalkerWalk
    STLK KK 3 A_Chase
    STLK L 3 A_StalkerWalk
    STLK L 3 A_Chase
    Loop
  Pain:
    STLK L 1 A_Pain
    Goto See
  Drop:
    STLK C 2 A_StalkerDrop
    STLK IHGFED 3
    Goto SeeFloor
  Death:
    STLK O 4
    STLK P 4 A_Scream
    STLK QRST 4
    STLK U 4 A_NoBlocking
    STLK VW 4
    STLK "XYZ[" 4 Bright
    Stop
  }
}