Classes:Loremaster

Note: Wait! Stop! You do not need to copy this actor's code into your project! Here's why: This actor is already defined in GZDoom, there's no reason to define it again. In fact, trying to define an actor with the same name will cause an error (because it already exists). If you want to make your own version of this actor, use inheritance. Definitions for existing actors are put on the wiki for reference purpose only.

The Loremaster
Actor type	Monster	Game	(Strife)
DoomEd Number	12	Class Name	Loremaster
Conversation ID	66, 63, 64	Puzzle Item ID	N/A

Classes: Actor → Loremaster
The Loremaster is the last of the five Sigil-possessing bosses in Strife (or the fourth, depending if you already killed the Oracle). He fires a chain which doesn't do much damage, although it pulls you away. This makes it extremely dangerous as you can lose a lot of health due to falling damage.

DECORATE definition

ACTOR Loremaster
{
  Health 800
  Speed 10
  Radius 15
  Height 56
  FloatSpeed 5
  Monster
  +FLOAT
  +NOBLOOD
  +NOGRAVITY
  +NOTDMATCH
  +FLOORCLIP
  +NOBLOCKMONST
  +INCOMBAT
  +LOOKALLAROUND
  +NOICEDEATH
  +NEVERRESPAWN
  DamageFactor "Fire", 0.5
  MinMissileChance 150
  Tag "$TAG_PRIEST" // "PRIEST"
  SeeSound "loremaster/sight"
  AttackSound "loremaster/attack"
  PainSound "loremaster/pain"
  DeathSound "loremaster/death"
  ActiveSound "loremaster/active"
  Obituary "$OB_LOREMASTER" // "%o couldn't escape from the Lore Master's grasp."
  DropItem "Junk"
  States
  {
  Spawn:
    PRST A 10 A_Look
    PRST B 10 A_SentinelBob
    Loop
  See:
    PRST A 4 A_Chase
    PRST A 4 A_SentinelBob
    PRST B 4 A_Chase
    PRST B 4 A_SentinelBob
    PRST C 4 A_Chase
    PRST C 4 A_SentinelBob
    PRST D 4 A_Chase
    PRST D 4 A_SentinelBob
    Loop
  Melee:
    PRST E 4 A_FaceTarget
    PRST F 4 A_CustomMeleeAttack((random[SpectreMelee](0, 255)&9)*5)
    PRST E 4 A_SentinelBob
    Goto See
  Missile:
    PRST E 4 A_FaceTarget
    PRST F 4 A_CustomMissile("LoreShot", 32, 0)
    PRST E 4 A_SentinelBob
    Goto See
  Death:
    PDED A 6
    PDED B 6 A_Scream
    PDED C 6
    PDED D 6 A_Fall
    PDED E 6
    PDED FGHIJIJIJKL 5
    PDED MNOP 4
    PDED Q 4 A_SpawnItemEx("AlienSpectre5", 0, 0, 0, 0, 0, random[spectrespawn](0, 255)*0.0078125, 0, SXF_NOCHECKPOSITION)
    PDED RS 4
    PDED T -1
    Stop
  }
}