|
Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things:
- You do NOT need to copy that actor, since it is already defined.
- In fact, it's not just useless, it will cause problems.
- If you want to modify it, or use a modified version, using inheritance is the way to go.
- The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.
|
Gargoyle
|
Actor type
|
Monster
|
Game
|
(Heretic)
|
DoomEd Number
|
66
|
Class Name
|
HereticImp
|
Spawn ID
|
5
|
Identifier
|
T_IMP
|
Classes: HereticImp
→HereticImpLeader
The weakest and first encountered monster in Heretic, these pests are barely more than a nuisance in most circumstances.
ACTOR HereticImp
{
Health 40
Radius 16
Height 36
Mass 50
Speed 10
PainChance 200
Monster
+FLOAT
+NOGRAVITY
+SPAWNFLOAT
+DONTOVERLAP
+MISSILEMORE
SeeSound "himp/sight"
AttackSound "himp/attack"
PainSound "himp/pain"
DeathSound "himp/death"
ActiveSound "himp/active"
Obituary "$OB_HERETICIMP"
HitObituary "$OB_HERETICIMPHIT"
action native A_ImpMsAttack();
action native A_ImpDeath();
action native A_ImpXDeath1();
action native A_ImpExplode();
States
{
Spawn:
IMPX ABCB 10 A_Look
Loop
See:
IMPX AABBCCBB 3 A_Chase
Loop
Melee:
IMPX DE 6 A_FaceTarget
IMPX F 6 A_CustomMeleeAttack(random[ImpMeAttack](5,12), "himp/attack", "himp/attack")
Goto See
Missile:
IMPX A 10 A_FaceTarget
IMPX B 6 A_ImpMsAttack
IMPX CBAB 6
Goto Missile+2
Pain:
IMPX G 3
IMPX G 3 A_Pain
Goto See
Death:
IMPX G 4 A_ImpDeath
IMPX H 5
Wait
XDeath:
IMPX S 5 A_ImpXDeath1
IMPX TU 5
IMPX V 5 A_Gravity
IMPX W 5
Wait
Crash:
IMPX I 7 A_ImpExplode
IMPX J 7 A_Scream
IMPX K 7
IMPX L -1
Stop
XCrash:
IMPX X 7
IMPX Y 7
IMPX Z -1
Stop
}
}