Classes:EntityBoss

From ZDoom Wiki
Jump to: navigation, search
Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things:
  1. You do not need to copy that actor, since it is already defined.
  2. In fact, it's not just useless, it's actually harmful as it can cause problems.
  3. If you want to modify it, or use a modified version, using inheritance is the way to go.
  4. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.
  5. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.
Alien entity
Actor type Monster Game MiniStrifeLogoIcon.png
DoomEd Number 128 Class Name EntityBoss
Conversation ID 74 Puzzle Item ID N/A


Classes: SpectralMonsterEntityBoss
The One God of the Sigil, the Entity uses all the sigil attacks. Dying while fighting it and recieving the bad ending is relevant to the level it is in, and not the Entity itself. The Entity splits into three sub-entities upon dying.

DECORATE definition

ACTOR EntityBoss : SpectralMonster 128
{
  Game Strife
  ConversationID 74, -1, -1
  Health 2500
  PainChance 255
  Speed 13
  Radius 130
  Height 200
  FloatSpeed 5
  Mass 1000
  Monster
  +SPECIAL
  +NOGRAVITY
  +FLOAT
  +SHADOW
  +NOTDMATCH
  +DONTMORPH
  +NOTARGET
  +NOBLOCKMONST
  +INCOMBAT
  +LOOKALLAROUND
  +SPECTRAL
  +NOICEDEATH
  MinMissileChance 150
  RenderStyle Translucent
  Alpha 0.5
  SeeSound "entity/sight"
  AttackSound "entity/melee"
  PainSound "entity/pain"
  DeathSound "entity/death"
  ActiveSound "entity/active"
  Obituary "$OB_ENTITY" // "%o felt the wrath of The One God."

  action native A_EntityAttack();
  action native A_EntityDeath();

  States
  {
  Spawn:
    MNAM A 100
    MNAM B 60 Bright
    MNAM CDEFGHIJKL 4 Bright
    MNAL A 4 Bright A_Look
    MNAL B 4 Bright A_SentinelBob
    Goto Spawn+12
  See:
    MNAL AB 4 Bright A_Chase
    MNAL C 4 Bright A_SentinelBob
    MNAL DEF 4 Bright A_Chase
    MNAL G 4 Bright A_SentinelBob
    MNAL HIJ 4 Bright A_Chase
    MNAL K 4 Bright A_SentinelBob
    Loop
  Melee:
    MNAL J 4 Bright A_FaceTarget
    MNAL I 4 Bright A_CustomMeleeAttack((random[SpectreMelee](0, 255)&9)*5)
    MNAL C 4 Bright
    Goto See+2
  Missile:
    MNAL F 4 Bright A_FaceTarget
    MNAL I 4 Bright A_EntityAttack
    MNAL E 4 Bright
    Goto See+10
  Pain:
    MNAL J 2 Bright A_Pain
    Goto See+6
  Death:
    MNAL L 7 Bright A_SpectreChunkSmall
    MNAL M 7 Bright A_Scream
    MNAL NO 7 Bright A_SpectreChunkSmall
    MNAL P 7 Bright A_SpectreChunkLarge
    MNAL Q 64 Bright A_SpectreChunkSmall
    MNAL Q 6 Bright A_EntityDeath
    Stop
  }
}