Classes:Templar

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do not need to copy that actor, since it is already defined. In fact, it's not just useless, it's actually harmful as it can cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.

Templar
Actor type	Monster	Game
DoomEd Number	3003	Class Name	Templar
Conversation ID	62, 61, 62	Puzzle Item ID	N/A

Classes: Actor → Templar
Templars are Strife enemies. Like Acolytes, they do not attack unless the alarm is active, and you can talk to them while they are idle. They attack by firing a Mauler blast, however this is weaker than the player's weapon. Despite their Mauler being most effective at close ranges, they have a mêlée attack.

DECORATE definition

ACTOR Templar
{
  Health 300
  PainChance 100
  Speed 8
  Radius 20
  Height 60
  Mass 500
  Monster
  +NOBLOOD
  +SEESDAGGERS
  +NOSPLASHALERT
  MaxDropOffHeight 32
  MinMissileChance 200
  SeeSound "templar/sight"
  PainSound "templar/pain"
  DeathSound "templar/death"
  ActiveSound "templar/active"
  CrushPainSound "misc/pcrush"
  Tag "$TAG_TEMPLAR" // "TEMPLAR"
  HitObituary "$OB_TEMPLARHIT" // "%o was clawed by a Templar."
  Obituary "$OB_TEMPLAR" // "%o was vaporized by a Templar."
  DropItem "EnergyPod"

  action native A_TemplarAttack();

  States
  {
  Spawn:
    PGRD A 5 A_Look2
    Loop
    PGRD B 10
    Loop
    PGRD C 10
    Loop
    PGRD B 10 A_Wander
    Loop
  See:
    PGRD AABBCCDD 3 A_Chase
    Loop
  Melee:
    PGRD E 8 A_FaceTarget
    PGRD F 8 A_CustomMeleeAttack(random[ReaverMelee](1, 8)*3, "reaver/blade")
    Goto See
  Missile:
    PGRD G 8 Bright A_FaceTarget
    PGRD H 8 Bright A_TemplarAttack
    Goto See
  Pain:
    PGRD A 2
    PGRD A 2 A_Pain
    Goto See
  Death:
    PGRD I 4 A_TossGib
    PGRD J 4 A_Scream
    PGRD K 4 A_TossGib
    PGRD L 4 A_NoBlocking
    PGRD MN 4
    PGRD O 4 A_TossGib
    PGRD "PQRSTUVWXYZ[" 4
    PGRD "\" -1
    Stop
  }
}