Classes:Sentinel

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do NOT need to copy that actor, since it is already defined. In fact, it's not just useless, it will cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.

Sentinel
Actor type	Monster	Game	(Strife)
DoomEd Number	3006	Class Name	Sentinel
Conversation ID	91	Puzzle Item ID	N/A

Classes: Actor → Sentinel
Sentinels are small, round robots from Strife. They attack by repeatedly firing laser shots which are very fast but do little damage. This can make them dangerous in large groups, but they don't have much health, and have 100% painchance. Use this to your advantage, as they counter-attack if you don't keep shooting them.

DECORATE definition

ACTOR Sentinel
{
  Health 100
  Painchance 255
  Speed 7
  Radius 23
  Height 53
  Mass 300
  Monster
  +SPAWNCEILING
  +NOGRAVITY
  +DROPOFF
  +NOBLOOD
  +NOBLOCKMONST
  +INCOMBAT
  +MISSILEMORE
  +LOOKALLAROUND
  +NEVERRESPAWN
  MinMissileChance 150
  SeeSound "sentinel/sight"
  DeathSound "sentinel/death"
  ActiveSound "sentinel/active"
  Obituary "$OB_SENTINEL" // "%o was shot down by a Sentinel."

  action native A_SentinelAttack();

  States
  {
  Spawn:
    SEWR A 10 A_Look
    Loop
  See:
    SEWR A 6 A_SentinelBob
    SEWR A 6 A_Chase
    Loop
  Missile:
    SEWR B 4 A_FaceTarget
    SEWR C 8 Bright A_SentinelAttack
    SEWR C 4 Bright A_SentinelRefire
    Goto Missile+1
  Pain:
    SEWR D 5 A_Pain
    Goto Missile+2
  Death:
    SEWR D 7 A_Fall
    SEWR E 8 Bright A_TossGib
    SEWR F 5 Bright A_Scream
    SEWR GH 4 Bright A_TossGib
    SEWR I 4
    SEWR J 5
    Stop
  }
}