Classes:MagePlayer

From ZDoom Wiki
Jump to navigation Jump to search
Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things:
  1. You do not need to copy that actor, since it is already defined.
  2. In fact, it's not just useless, it's actually harmful as it can cause problems.
  3. If you want to modify it, or use a modified version, using inheritance is the way to go.
  4. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.
  5. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.
Daedolon
Actor type Player Game MiniHexenLogoIcon.png
DoomEd Number None Class Name MagePlayer


ActorPlayerPawn MagePlayer

The Mage is one of the three character classes available for play in Hexen. He's the frailest character, but is totally oriented toward ranged combat. His weapons are:

  • Sapphire Wand: A magic weapon that fires an ultra-fast projectile that can rip through lines of enemies. It deals low damage, but uses no mana and is the only long-range starting weapon in Hexen.
  • Frost Shards: A spell fueled by blue mana that launches a cone of icey darts that can freeze an enemy in its tracks. Using this spell upclose acquaints your target with a freezing touch, which is more effect. In a way, similar to its thematic reverse, the Cleric's Firestorm.
  • Arc of Death: This spell uses green mana to cast out a vertical collumn of lightning that blasts your enemies with impunity. Once hit, the bolt of electicity "sticks" to the target and deals damage continously until the target is killed or the spell dissipates. This attack can travel over cliffs and will continue until it hits a wall or monster.
  • Bloodscourge: This powerful and sinister magic staff uses both mana types to throw out three homing magic projectiles that blast through enemies. These magic missiles seek out their own targets and will continue to look for new targets until it hits a wall, floor, or ceiling, which causes it to explode, dealing larget amounts of splash damage. Before using Bloodscourge in combat, the Mage must first assemble it by finding the three relevant weapon pieces.

Contrarily to other player classes, the Hexen player classes can not easily use additional weapons. While it is possible in KEYCONF to change which weapon is associated to which slot, a Mage can still only select these four weapons with the keys bound to weapon slots. (However, the keys bound to next and previous weapon, the use console command, and the automatic weapon switching when running out of ammo, can still equip another weapon.) A Mage picking up a Cleric or Fighter weapon will only gain ammunitions from them, though it is still possible to give him the illegal weapons with the console, ACS, or DECORATE.

A Mage under the effect of an Icon of the Defender will reflect incoming projectiles away. He uses the fléchettes as timebombs, which require cleverness to be used efficiently. When he uses a Mystic Ambit Incant, his nearby allies resplenish their mana.

Character Summary

In a world named Chronos, Daedolon the Mage is the only remaining free member of his order, the Arcanum. All others have been turned into mind-controled slave under the command of the Arcanum's treacherous leader, Menelkir, who is himself a thrall to the Serpent Rider Korax. Just like his similarly-fated friends Baratus the Fighter and Parias the Cleric, Daedolon intends to free his world from Korax and the Serpent Rider's hellish hordes by personally eliminating each and everyone of his enemies.

In game, Daedolon appears as a typical fantasy wizard: wearing a hooded robe, an amulet, and a gem-tipped staff. The staff may be meant to be the Sapphire Wand or the Bloodscourge, but doesn't actually look like either.

DECORATE definition

ACTOR MagePlayer : PlayerPawn
{
  Health 100
  ReactionTime 0
  PainChance 255
  Radius 16
  Height 64
  Speed 1
  +NOSKIN
  +NODAMAGETHRUST
  +NOTHRUSTWHENINVUL
  PainSound "PlayerMagePain"
  RadiusDamageFactor 0.25
  Player.JumpZ 9
  Player.Viewheight 48
  Player.SpawnClass "Mage"
  Player.DisplayName "Mage"
  Player.SoundClass "mage"
  Player.ScoreIcon "MAGEFACE"
  Player.InvulnerabilityMode "Reflective"
  Player.HealRadiusType "Mana"
  Player.HexenArmor 5, 5, 15, 10, 25
  Player.StartItem "MWeapWand"
  Player.ForwardMove 0.88, 0.92
  Player.SideMove 0.875, 0.925
  Player.Portrait "P_MWALK1"
  Player.WeaponSlot 1, MWeapWand
  Player.WeaponSlot 2, MWeapFrost
  Player.WeaponSlot 3, MWeapLightning
  Player.WeaponSlot 4, MWeapBloodscourge
  Player.FlechetteType "ArtiPoisonBag2"

  Player.ColorRange 146, 163
  Player.ColorSet     0, "Blue",          146, 163,     161
  Player.ColorSetFile 1, "Red",           "TRANTBL7",  0xB3
  Player.ColorSetFile 2, "Gold",          "TRANTBL8",  0x8C
  Player.ColorSetFile 3, "Dull Green",    "TRANTBL9",  0x41
  Player.ColorSetFile 4, "Green",         "TRANTBLA",  0xC9
  Player.ColorSetFile 5, "Gray",          "TRANTBLB",  0x30
  Player.ColorSetFile 6, "Brown",         "TRANTBLC",  0x72
  Player.ColorSetFile 7, "Purple",        "TRANTBLD",  0xEE

  States
  {
  Spawn:
    MAGE A -1
    Stop
  See:
    MAGE ABCD 4
    Loop
  Missile:
  Melee:
    MAGE EF 8
    Goto Spawn
  Pain:
    MAGE G 4
    MAGE G 4 A_Pain
    Goto Spawn
  Death:
    MAGE H 6
    MAGE I 6 A_PlayerScream
    MAGE JK 6
    MAGE L 6 A_NoBlocking
    MAGE M 6
    MAGE N -1
    Stop     
  XDeath:
    MAGE O 5 A_PlayerScream
    MAGE P 5
    MAGE R 5 A_NoBlocking
    MAGE STUVW 5
    MAGE X -1
    Stop
  Ice:
    MAGE Y 5 A_FreezeDeath
    MAGE Y 1 A_FreezeDeathChunks
    Wait
  Burn:
    FDTH E 5 Bright A_PlaySound("*burndeath")
    FDTH F 4 Bright
    FDTH G 5 Bright
    FDTH H 4 Bright A_PlayerScream
    FDTH I 5 Bright
    FDTH J 4 Bright
    FDTH K 5 Bright
    FDTH L 4 Bright
    FDTH M 5 Bright
    FDTH N 4 Bright
    FDTH O 5 Bright
    FDTH P 4 Bright
    FDTH Q 5 Bright
    FDTH R 4 Bright
    FDTH S 5 Bright A_NoBlocking
    FDTH T 4 Bright
    FDTH U 5 Bright
    FDTH V 4 Bright
    ACLO E 35 A_CheckPlayerDone
    Wait
    ACLO E 8
    Stop
  }
}