Classes:Cacodemon

From ZDoom Wiki
(Redirected from Cacodemon)
Jump to: navigation, search
Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things:
  1. You do not need to copy that actor, since it is already defined.
  2. In fact, it's not just useless, it's actually harmful as it can cause problems.
  3. If you want to modify it, or use a modified version, using inheritance is the way to go.
  4. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.
  5. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.
Cacodemon
Actor type Monster Game MiniDoomLogoIcon.png
DoomEd Number 3005 Class Name Cacodemon
Spawn ID 19 Identifier T_CACODEMON


Classes: Cacodemon
 →DeadCacodemon
 →StealthCacodemon


The Cacodemon has nothing better to do than to fly around and shoot purple balls at you through their mouth. They like biting up close so it's a good idea to keep your distance.


DECORATE definition

ACTOR Cacodemon
{
  Health 400
  Radius 31
  Height 56
  Mass 400
  Speed 8
  PainChance 128
  Monster
  +FLOAT
  +NOGRAVITY
  SeeSound "caco/sight"
  PainSound "caco/pain"
  DeathSound "caco/death"
  ActiveSound "caco/active"
  Obituary "$OB_CACO"
  HitObituary "$OB_CACOHIT"
  States
  {
  Spawn:
    HEAD A 10 A_Look
    Loop
  See:
    HEAD A 3 A_Chase
    Loop
  Missile:
    HEAD BC 5 A_FaceTarget
    HEAD D 5 Bright A_HeadAttack
    Goto See
  Pain:
    HEAD E 3
    HEAD E 3 A_Pain
    HEAD F 6
    Goto See
  Death:
    HEAD G 8
    HEAD H 8 A_Scream
    HEAD IJ 8
    HEAD K 8 A_NoBlocking
    HEAD L -1 A_SetFloorClip
    Stop
  Raise:
    HEAD L 8 A_UnSetFloorClip
    HEAD KJIHG 8
    Goto See
  }
}