Classes:Revenant

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do not need to copy that actor, since it is already defined. In fact, it's not just useless, it's actually harmful as it can cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.

Revenant
Actor type	Monster	Game
DoomEd Number	66	Class Name	Revenant
Spawn ID	20	Identifier	T_REVENANT

Classes: Revenant
 →StealthRevenant

The Revenant, a bag of bones with armour, will send heatseeking missiles into its targets from a distance and punch them when up close.

DECORATE definition

ACTOR Revenant 66
{
  Game Doom
  SpawnID 20
  Health 300
  Radius 20
  Height 56
  Mass 500
  Speed 10
  PainChance 100
  Monster
  MeleeThreshold 196
  +MISSILEMORE 
  +FLOORCLIP
  SeeSound "skeleton/sight"
  PainSound "skeleton/pain"
  DeathSound "skeleton/death"
  ActiveSound "skeleton/active"
  MeleeSound "skeleton/melee"
  HitObituary "$OB_UNDEADHIT" // "%o was punched by a revenant."
  Obituary "$OB_UNDEAD" // "%o couldn't evade a revenant's fireball."
  States
  {
  Spawn:
    SKEL AB 10 A_Look
    Loop
  See:
    SKEL AABBCCDDEEFF 2 A_Chase
    Loop
  Melee:
    SKEL G 1 A_FaceTarget
    SKEL G 6 A_SkelWhoosh
    SKEL H 6 A_FaceTarget
    SKEL I 6 A_SkelFist
    Goto See
  Missile:
    SKEL J 1 Bright A_FaceTarget
    SKEL J 9 Bright A_FaceTarget
    SKEL K 10 A_SkelMissile
    SKEL K 10 A_FaceTarget
    Goto See
  Pain:
    SKEL L 5
    SKEL L 5 A_Pain
    Goto See
  Death:
    SKEL LM 7
    SKEL N 7 A_Scream
    SKEL O 7 A_NoBlocking
    SKEL P 7
    SKEL Q -1
    Stop
  Raise:
    SKEL Q 5
    SKEL PONML 5
    Goto See
  }
}