Classes:Demon

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do not need to copy that actor, since it is already defined. In fact, it's not just useless, it's actually harmful as it can cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.

Demon
Actor type	Monster	Game
DoomEd Number	3001	Class Name	Demon
Spawn ID	8	Identifier	T_DEMON

Classes: Demon
 →DeadDemon
 →Spectre
 →StealthDemon

The Demon also known as Pinky Demon, is the first and only monster which won't shoot or fire at you from a distance. Instead, it will hunt you down and get up close and personal to bite you. Can be a low to high threat, depending on the number of Demons.

DECORATE definition

ACTOR Demon 3002
{
  Game Doom
  SpawnID 8
  Health 150
  PainChance 180
  Speed 10
  Radius 30
  Height 56
  Mass 400
  Monster
  +FLOORCLIP
  SeeSound "demon/sight"
  AttackSound "demon/melee"
  PainSound "demon/pain"
  DeathSound "demon/death"
  ActiveSound "demon/active"
  Obituary "$OB_DEMONHIT" // "%o was bit by a demon."
  States
  {
  Spawn:
    SARG AB 10 A_Look
    Loop
  See:
    SARG AABBCCDD 2 Fast A_Chase
    Loop
  Melee:
    SARG EF 8 Fast A_FaceTarget
    SARG G 8 Fast A_SargAttack
    Goto See
  Pain:
    SARG H 2 Fast
    SARG H 2 Fast A_Pain
    Goto See
  Death:
    SARG I 8
    SARG J 8 A_Scream
    SARG K 4
    SARG L 4 A_NoBlocking
    SARG M 4
    SARG N -1
    Stop
  Raise:
    SARG N 5
    SARG MLKJI 5
    Goto See
  }
}