Classes:Crusader

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do NOT need to copy that actor, since it is already defined. In fact, it's not just useless, it will cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.

Crusader
Actor type	Monster	Game	(Strife)
DoomEd Number	3005	Class Name	Crusader
Conversation ID	63	Puzzle Item ID	N/A

Classes: Crusader
A bipedal robot, built and controlled by the Order. It's armed with a Rocket Launcher, a flamethrower for close combat and a decent amount of health.

DECORATE definition

ACTOR Crusader
{
  Speed 8
  Radius 40
  Height 56
  Mass 400
  Health 400
  PainChance 128
  Monster
  +FLOORCLIP
  +DONTMORPH
  +MISSILEMORE
  +INCOMBAT
  +NOICEDEATH
  +NOBLOOD
  MinMissileChance 120
  MaxDropoffHeight 32
  DropItem "EnergyPod", 256, 20
  SeeSound "crusader/sight"
  PainSound "crusader/pain"
  DeathSound "crusader/death"
  ActiveSound "crusader/active"
  Obituary "$OB_CRUSADER" // "%o was swept away by a Crusader."

  action native A_CrusaderChoose();
  action native A_CrusaderSweepLeft();
  action native A_CrusaderSweepRight();
  action native A_CrusaderRefire();
  action native A_CrusaderDeath();

  States
  {
  Spawn:
    ROB2 Q 10 A_Look
    Loop
  See:
    ROB2 AABBCCDD 3 A_Chase
    Loop
  Missile:
    ROB2 E 3 Slow A_FaceTarget
    ROB2 F 2 Slow Bright A_CrusaderChoose
    ROB2 E 2 Slow Bright A_CrusaderSweepLeft
    ROB2 F 3 Slow Bright A_CrusaderSweepLeft
    ROB2 EF 2 Slow Bright A_CrusaderSweepLeft
    ROB2 EFE 2 Slow Bright A_CrusaderSweepRight
    ROB2 F 2 Slow A_CrusaderRefire
    Loop
  Pain:
    ROB2 D 1 Slow A_Pain
    Goto See
  Death:
    ROB2 G 3 A_Scream
    ROB2 H 5 A_TossGib
    ROB2 I 4 Bright A_TossGib
    ROB2 J 4 Bright A_Explode(64, 64, 1, 1)
    ROB2 K 4 Bright A_Fall
    ROB2 L 4 A_Explode(64, 64, 1, 1)
    ROB2 MN 4 A_TossGib
    ROB2 O 4 A_Explode(64, 64, 1, 1)
    ROB2 P -1 A_CrusaderDeath
    Stop
  }
}