Classes:ChaingunGuy

Note: Wait! Stop! You do not need to copy this actor's code into your project! Here's why: This actor is already defined in GZDoom, there's no reason to define it again. In fact, trying to define an actor with the same name will cause an error (because it already exists). If you want to make your own version of this actor, use inheritance. Definitions for existing actors are put on the wiki for reference purpose only.

Heavy Weapon Dude
Actor type	Monster	Game	(Doom2)
DoomEd Number	65	Class Name	ChaingunGuy
Spawn ID	2	Identifier	T_CHAINGUY

Classes: ChaingunGuy
 →StealthChaingunGuy

The Chaingun Zombie, aka "Former Human Commando", totes a huge chaingun and can whittle a player's health down in seconds. Luckily, they can't take much damage and can be easily dispatched. They drop their chaingun when they die. They will even mow through their own ranks if you can get around them.

ZScript definition

Note: The ZScript definition below is for reference and may be different in the current version of GZDoom.The most up-to-date version of this code can be found on GZDoom GitHub.

class ChaingunGuy : Actor
{
	Default
	{
		Health 70;
		Radius 20;
		Height 56;
		Mass 100;
		Speed 8;
		PainChance 170;
		Monster;
		+FLOORCLIP
		SeeSound "chainguy/sight";
		PainSound "chainguy/pain";
		DeathSound "chainguy/death";
		ActiveSound "chainguy/active";
		AttackSound "chainguy/attack";
		Obituary "$OB_CHAINGUY";
		Tag "$FN_HEAVY";
		Dropitem "Chaingun";
	}
	States
	{
	Spawn:
		CPOS AB 10 A_Look;
		Loop;
	See:
		CPOS AABBCCDD 3 A_Chase;
		Loop;
	Missile:
		CPOS E 10 A_FaceTarget;
		CPOS FE 4 BRIGHT A_CPosAttack;
		CPOS F 1 A_CPosRefire;
		Goto Missile+1;
	Pain:
		CPOS G 3;
		CPOS G 3 A_Pain;
		Goto See;
	Death:
		CPOS H 5;
		CPOS I 5 A_Scream;
		CPOS J 5 A_NoBlocking;
		CPOS KLM 5;
		CPOS N -1;
		Stop;
	XDeath:
		CPOS O 5;
		CPOS P 5 A_XScream;
		CPOS Q 5 A_NoBlocking;
		CPOS RS 5;
		CPOS T -1;
		Stop;
	Raise:
		CPOS N 5;
		CPOS MLKJIH 5;
		Goto See;
	}
}

DECORATE definition

Warning: This is legacy code, kept for archival purposes only. DECORATE is deprecated in GZDoom and is completely superseded by ZScript. GZDoom internally uses the ZScript definition above.

ACTOR ChaingunGuy
{
  Health 70
  Radius 20
  Height 56
  Mass 100
  Speed 8
  PainChance 170
  Monster
  +FLOORCLIP
  SeeSound "chainguy/sight"
  PainSound "chainguy/pain"
  DeathSound "chainguy/death"
  ActiveSound "chainguy/active"
  AttackSound "chainguy/attack"
  Obituary "$OB_CHAINGUY"
  Dropitem "Chaingun"
  States
  {
  Spawn:
    CPOS AB 10 A_Look
    Loop
  See:
    CPOS AABBCCDD 3 A_Chase
    Loop
  Missile:
    CPOS E 10 A_FaceTarget
    CPOS FE 4 Bright A_CPosAttack
    CPOS F 1 A_CPosRefire
    Goto Missile+1
  Pain:
    CPOS G 3
    CPOS G 3 A_Pain
    Goto See
  Death:
    CPOS H 5
    CPOS I 5 A_Scream
    CPOS J 5 A_NoBlocking
    CPOS KLM 5
    CPOS N -1
    Stop
  XDeath:
    CPOS O 5 
    CPOS P 5 A_XScream
    CPOS Q 5 A_NoBlocking
    CPOS RS 5
    CPOS T -1
    Stop
  Raise:
    CPOS N 5
    CPOS MLKJIH 5
    Goto See
  }
}