Classes:Centaur

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do NOT need to copy that actor, since it is already defined. In fact, it's not just useless, it will cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.

Centaur
Actor type	Monster	Game	(Hexen)
DoomEd Number	107	Class Name	Centaur
Spawn ID	1	Identifier	T_CENTAUR

Classes: Centaur
 →CentaurLeader
 →CentaurMash

Centaurs are armored, vaguely leonine chimeras of men and horses, and one of the most often encountered enemy in Hexen. They have no ranged attack, though their leaders, the Slaughtaurs, have one; but they have a special power granted by their shield, which make them invulnerable to most forms of attack when they use it. This invulnerability, combined with their reasonable supply of hit points, can make them very frustrating enemies until one gets the top-tier weapons. Along with Afrits and Ettins, they are often spawned periodically through ACS to prevent a map from being empty for too long; which can make them quite annoying after a while.

Ettins and Centaurs, when hurt by a poison cloud or by a mage's arc of death, emit the funny "puppy beat" sound. Centaurs are especially vulnerable to electric attacks.

DECORATE definition

ACTOR Centaur
{
  Health 200
  PainChance 135
  Speed 13
  Height 64
  Mass 120
  Monster
  +FLOORCLIP
  +TELESTOMP
  +SHIELDREFLECT
  SeeSound "CentaurSight"
  AttackSound "CentaurAttack"
  PainSound "CentaurPain"
  DeathSound "CentaurDeath"
  ActiveSound "CentaurActive"
  HowlSound "PuppyBeat"
  Obituary "$OB_CENTAUR"
  DamageFactor "Electric", 3
  States
  {
  Spawn:
    CENT AB 10 A_Look
    Loop
  See:
    CENT ABCD 4 A_Chase
    Loop
  Pain:
    CENT G 6 A_Pain
    CENT G 6 A_SetReflectiveInvulnerable
    CENT EEE 15 A_CentaurDefend
    CENT E 1 A_UnsetReflectiveInvulnerable
    Goto See
  Melee:
    CENT H 5 A_FaceTarget
    CENT I 4 A_FaceTarget
    CENT J 7 A_CustomMeleeAttack(random[CentaurAttack](3, 9))
    Goto See
  Death:
    CENT K 4
    CENT L 4 A_Scream
    CENT MN 4
    CENT O 4 A_NoBlocking
    CENT PQ 4
    CENT R 4 A_QueueCorpse
    CENT S 4
    CENT T -1
    Stop
  XDeath:
    CTXD A 4
    CTXD B 4 A_NoBlocking
    CTXD C 0 A_SpawnItemEx("CentaurSword", 0, 0, 45, 1 + random[CentaurDrop](-128,127)*0.03125,
                           1 + random[CentaurDrop](-128,127)*0.03125, 8 + random[CentaurDrop](0,255)*0.015625, 270)
    CTXD C 4 A_SpawnItemEx("CentaurShield", 0, 0, 45, 1 + random[CentaurDrop](-128,127)*0.03125,
                           1 + random[CentaurDrop](-128,127)*0.03125, 8 + random[CentaurDrop](0,255)*0.015625, 90)
    CTXD D 3 A_Scream
    CTXD E 4 A_QueueCorpse
    CTXD F 3
    CTXD G 4
    CTXD H 3
    CTXD I 4
    CTXD J 3
    CTXD K -1
  Ice:
    CENT U 5 A_FreezeDeath
    CENT U 1 A_FreezeDeathChunks
    Wait
  }
}