Classes:Archvile

From ZDoom Wiki

Arch-Vile
Actor type	Monster	Game
DoomEd Number	64	Class Name	Archvile
Spawn ID	111	Identifier	T_VILE

Classes: Archvile

 →StealthArchvile

The Archvile's primary attack sends a huge flame into its target, which then punts it up into the air and knocking large amounts of health. The only way to dodge it is to get behind a wall fast, or hurt the Archvile before it can complete the attack. The Archvile can also resurrect it's hellish brethren. However, Archviles cannot resurrect the Cyberdemon, Spider Mastermind, Lost Soul, Pain Elemental, or fellow Archviles. The Archvile is lacking from the console versions of Doom.

The Archvile can only resurrect an actor if they have a Raise state in their Decorate definition. By default, the large enemies (listed above) do not have this state and so the Archvile won't attempt to resurrect them. If you want to create a new actor inherited from one with a Raise state, but don't want the new monster to be resurrectable, you can disable the Raise state using the following code in your actor:

Raise:
  Stop

DECORATE definition

ACTOR Archvile 64
{
  Game Doom
  SpawnID 111
  Health 700
  Radius 20
  Height 56
  Mass 500
  Speed 15
  PainChance 10
  Monster
  MaxTargetRange 896
  +QUICKTORETALIATE 
  +FLOORCLIP 
  +NOTARGET
  SeeSound "vile/sight"
  PainSound "vile/pain"
  DeathSound "vile/death"
  ActiveSound "vile/active"
  MeleeSound "vile/stop"
  Obituary "$OB_VILE" // "%o was incinerated by an archvile."
  States
  {
  Spawn:
    VILE AB 10 A_Look
    Loop
  See:
    VILE AABBCCDDEEFF 2 A_VileChase
    Loop
  Missile:
    VILE G 0 BRIGHT A_VileStart
    VILE G 10 BRIGHT A_FaceTarget
    VILE H 8 BRIGHT A_VileTarget
    VILE IJKLMN 8 BRIGHT A_FaceTarget
    VILE O 8 BRIGHT A_VileAttack
    VILE P 20 BRIGHT
    Goto See
  Heal:
    VILE "[\]" 10 BRIGHT
    Goto See
  Pain:
    VILE Q 5   
    VILE Q 5 A_Pain
    Goto See
  Death:
    VILE Q 7
    VILE R 7 A_Scream
    VILE S 7 A_NoBlocking
    VILE TUVWXY 7
    VILE Z -1
    Stop
  }
}